Edukiak

# CreateUnoService funtzioa

UNO zerbitzu baten instantzia bat sortzen du ProcessServiceManager bidez.

### Sintaxia:

         CreateUnoService(serviceName As String) As Object

### Return type:

Object

### Parametroak:

Name | Type | Description
--- | --- | ---
serviceName | String | The service name. Erabilgarri dauden zerbitzuen zerrenda bat ikusteko, joan com::sun::star Module erreferentzia-orrira.

### Adibidea:

Beheko adibidean, com.sun.star.ucb.SimpleFileAccess zerbitzua darabilen FileExists funtzioa sortzen da, emandako bide-izen bat existitzen den fitxategi bat den ala ez aztertzeko.

        Function FileExists(sPath as String) As Boolean
            Dim svcSFA As Object
            Set svcSFA = CreateUnoService("com.sun.star.ucb.SimpleFileAccess")
            Dim bExists As Boolean : bExists = svcSFA.exists(sPath)
            Dim bIsFolder As Boolean : bIsFolder = svcSFA.IsFolder(sPath)
            FileExists = bExists And Not bIsFolder
        End Function ' FileExists

UNO zerbitzuak lineako dokumentazio zabala dute api.libreoffice.org webgunean. Begiratu SimpleFileAccess zerbitzuaren erreferentzia-orria goiko adibidean erabili den zerbitzuak eskaintzen dituen metodoak ezagutzeko.

### Adibidea:

The following code uses the service com.sun.star.ui.dialogs.FilePicker to show an open file dialog:

    Sub Main
       fIzena = FileOpenDialog ("Hautatu fitxategi bat")
       print "aukeratutako fitxategia: "+fIzena
    End Sub

    Function FileOpenDialog(title As String) As String
       res = com.sun.star.ui.dialogs.ExecutableDialogResults
       filepicker = CreateUnoService("com.sun.star.ui.dialogs.FilePicker")
       With filepicker
          .Title = title
          .MultiSelectionMode = True
          .appendFilter("Calc docs","*.ods;*.csv;*.123")
          .appendFilter("Writer or Base docs","*.odt;*.odb")
          .appendFilter("All files","*.*")
           If res.OK = .execute() Then
              files = .getSelectedFiles()
              FileOpenDialog=files(0)
           EndIf
       End With
    End Function ' FileOpenDialog

Erlazionatutako gaiak

CreateUnoServiceWithArguments funtzioa

UNO objektuak, funtzioak eta zerbitzuak

Calc funtzioak makroetan erabiltzea