MIDDEL.HVIS funktion

Indhold
Indholdsfortegnelse 🔎︎

## MIDDEL.HVIS-funktion

Returnerer det aritmetiske gennemsnit af alle celler i et område der tilfredsstiller en given betingelse. MIDDEL.HVIS funktionen summerer alle resultater der passer den logiske test, og dividerer summen med antallet af valgte værdier.

Denne funktion er tilgængelig siden LibreOffice 4.0.

#### Syntaks

MIDDEL.HVIS(Område; Kriterie [; Gennemsnit_Område])

Område – påkrævet argument. Et område, navnet på et navngivet område eller en etiket for en kolonne eller en række, som indeholder gennemsnitstal, tal eller tekst for betingelserne.

Kriterie: Et kriterie er en enkelt celle, henvisning, tal eller tekst. Det bruges i sammenligninger med celleindhold.

En henvisning til en tom celle fortolkes som den numeriske værdi 0.

Et matchende udtryk kan være:

- Et tal eller en logisk værdi. Et matchende celleindhold er lig med tallet eller den logiske værdi.

- En værdi begyndende med en komparator (<, <=, =, >, >=, <>).

  Ved =: hvis værdien er tom, matcher den tomme celler.

  Ved <>: hvis værdien er tom, matcher den ikke-tomme celler.

  Ved <>: hvis værdien ikke er tom, matcher den ethvert celleindhold, undtagen værdien, herunder tomme celler.

  Bemærk: "=0" matcher ikke tomme celle.

  Ved = og <>: hvis værdien ikke er tom og ikke kan fortolkes som typen Tal eller en af dens undertyper og egenskaben Søgekriterier = og <> skal gælde hele celler er markeret, sker sammenligningen med hele celleindholdet, hvis den ikke er markeret, sker sammenligningen med enhver delmængde af feltet, der matcher kriterierne. Ved = og <>: hvis værdien ikke er tom og ikke kan fortolkes som typen Tal eller en en af dens undertyper, gælder ...

- Anden tekstværdi. Hvis egenskaben Søgekriterier = og <> skal gælde hele celler er sand, sker sammenligningen med hele celleindhold, hvis falsk, sker sammenligningen med enhver delmængde af feltet, der matcher kriterierne. Udtrykket kan indeholde tekst, tal, udtryk eller jokere (, hvis aktiveret i indstillingerne Beregning).

Søgningen understøtter jokere eller regulære udtryk . Når regulære udtryk er aktiveret, kan du indtaste "al.*", for eksempel for at finde det første sted, hvor "al" følges af vilkårlige tegn. Hvis du vil søge efter en tekst, som også er et regulært udtryk, kan du enten sætte et "\" foran hvert tegn, eller lukke teksten inde i \Q…\E. du kan også slå den automatiske evaluering af jokere eller regulære udtryk til og res i LibreOffice ▸ Indstillinger Funktioner ▸ Indstillinger ▸ LibreOffice Calc ▸ Beregn.

Når du bruger funktioner, hvor et eller flere argumenter er søgekriterie-strenge, der repræsenterer et regulært udtryk, er det første forsøg at konvertere strengkriterierne til tal. For eksempel vil ".0" konveretres til 0.0 og så videre. Hvis det lykkes, vil matchet ikke være et et regulært udtryk, men et numerisk match. Hvis du imidlertid skifter til lokalisering, hvor decimaltegnet ikke er punktum, kommer konverteringen fungere. For at gennemtvingen evalueringen af det regulære udtryk frem for et numerisk udtryk bruger du et udtryk som ikke kan fejllæses som numerisk, såsom ".[0]", ".\0" eller "(?i).0".

Gennemsnit_Område – valgfrit. Det er et område af værdier, som der skal beregnes gennemsnit for.

Hvis Gennemsnits_område ikke er angivet, bruges Område til både beregningen af gennemsnittet og søgningen i overensstemmelse med betingelsen. Hvis Gennemsnits_område er angivet, bruges Område udelukkende til test af betingelsen, mens Gennemsnits_område bruges til beregning af gennemsnittet.

Denne funktion er en del af Open Document Format for Office Applications (OpenDocument) standard Version 1.2. (ISO/IEC 26300:2-2015)

Hvis en celle i et område af værdier, som der skal beregnes middelværdi for, er tom eller indeholder tekst, ignorerer funktionen MIDDEL.HVIS cellen.
Hvis hele området er tomt, kun indeholder tekst, eller samtlige værdier ikke tilfredsstiller betingelserne (eller en kombination af dem), returnerer funktionen fejlen #DIV/0!.

#### Eksempel

Betragt den følgende tabel

| A | B | C
1 | Produktnavn | Salg | Indtægt
2 | blyant | 20 | 65
3 | kuglepen | 35 | 85
4 | notesblok | 20 | 190
5 | bog | 17 | 180
6 | penalhus | ikke | ikke

I alle eksempler herunder, indeholder området for beregning af summen række #6, men den ignoreres, fordi den indeholder tekst.

#### Simpelt brug

=MIDDEL.HVIS(B2:B6;"<35")

Beregner gennemsnittet for værdier i området B2:B6 som er mindre end 35. Returnerer 19, fordi anden række ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;"<"&MAX(B2:B6))

Beregner gennemsnittet for værdierne i det samme område, som er mindre end den maksimale værdi i dette område. Returnerer 19, fordi den højeste værdi (anden række) ikke medregnes i gennemsnittet.

=MIDDEL.HVIS(B2:B6;">"&MINDSTE(B2:B6;1))

Beregner gennemsnittet af værdier i det samme område, som er større end den første mindste værdi i området. Returnerer 25, fordi den første mindste værdi (fjerde række) ikke medregnes i gennemsnittet.

#### Brug af gennemsnit_område

=MIDDEL.HVIS(B2:B6;"<35";C2:C6)

Funktionen finder de værdier, som er mindre end 35 i området B2:B6, og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 145, fordi anden række ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;">"&MIN(B2:B6);C2:C6)

Funktionen finder de værdier fra området B2:B6, som er større end den mindste værdi og beregner gennemsnittet af korresponderende værdier fra området C2:C6. Returnerer 113,3, fordi fjerde række (hvor den mindste værdi er) ikke medregnes i beregningen.

=MIDDEL.HVIS(B2:B6;"<"&STØRSTE(B2:B6;2);C2:C6)

Denne funktion finder hvilke værdier fra området B2:B6 som er mindre end den næsthøjeste værdi i området B2:B6, og beregner gennemsnittet for de korresponderende værdier fra området C2:C6. Returnerer 180, fordi kun fjerde række indgår i beregningen.

#### Brug af regulære udtryk

=MIDDEL.HVIS(A2:A6;"pen";B2:B6)

Denne funktion finder de celler fra området A2:A6 som indeholder ordet “pen”, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Returnerer 35, fordi kun den anden række indgår i beregningen. Søgningen sker i området A2:A6, men værdierne returneres fra området B2:B6.

=MIDDEL.HVIS(A2:A6;"pen.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som begynder med “pen” og slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 27,5, fordi også ordet “pencil” lever op til betingelserne, og både første og anden række indgår i beregningen.

=MIDDEL.HVIS(A2:A6;".*book.*";B2:B6)

Denne funktion finder de celler i området A2:A6 som indeholder “book” og starter eller slutter med enhver kombination af tegn, og beregner gennemsnittet af værdierne fra det korresponderende område B2:B6. Returnerer 18,5, fordi kun tredje og fjerde række indgår i beregningen.

#### Reference til en celle som kriterie

Hvis du har brug for let at ændre et kriterie, kan du angive det i en separat celle og bruge en reference til denne celle i betingelsen i MIDDEL.HVIS-funktionen.

=MIDDEL.HVIS(A2:A6;".*"&E2&".*";B2:B6)

Denne funktion finder hvilke celler i området A2:A6 som indeholder en kombination af tegn som specificeres i E2 startende og sluttende med enhver kombination af tegn, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = book, returnerer funktionen 18,5.

=MIDDEL.HVIS(B2:B6;"<&E2;C2:C6)

Denne funktion finder de celler fra området A2:A6 som er mindre end værdien specificeret i E2, og beregner gennemsnittet af de korresponderende værdier fra området B2:B6. Hvis E2 = 35, returnerer funktionen 145.

Relaterede emner

MIDDEL, MIDDELV, MAD

TÆL.FLERE.HVIS, MINHVISER, MAKSHVISER, MIDDEL.HVIS, SUM.FLERE.HVIS

Liste over regulære udtryk