Isi
Indeks 🔎︎

# fungsi MAXIFS

Mengembalikan nilai sel maksimum dalam rentang yang memenuhi beberapa kriteria dalam beberapa rentang.

#### Sintaksis

MAXIFS(Func_Range; Range1; Criterion[; Range2; Criterion2][; … ; [Range127; Criterion127]])

Func_Range – argumen yang dibutuhkan. Rentang sel, nama dari rentang yang dinamai atau label kolom atau baris yang berisi nilai untuk menghitung maksimum.

Range1 – required argument. It is a range of cells, a name of a named range, or a label of a column or a row, to which the corresponding criterion is to be applied.

Criterion: A criterion is a single cell Reference, Number or Text. It is used in comparisons with cell contents.

A reference to an empty cell is interpreted as the numeric value 0.

A matching expression can be:

- A Number or Logical value. A matching cell content equals the Number or Logical value.

- A value beginning with a comparator (<, <=, =, >, >=, <>).

  For =, if the value is empty it matches empty cells.

  For <>, if the value is empty it matches non-empty cells.

  For <>, if the value is not empty it matches any cell content except the value, including empty cells.

  Note: "=0" does not match empty cells.

  For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes and the property Search criteria = and <> must apply to whole cells is checked, comparison is against the entire cell contents, if unchecked, comparison is against any subpart of the field that matches the criteria. For = and <>, if the value is not empty and can not be interpreted as a Number type or one of its subtypes applies.

- Other Text value. If the property Search criteria = and <> must apply to whole cells is true, the comparison is against the entire cell contents, if false, comparison is against any subpart of the field that matches the criteria. The expression can contain text, numbers, regular expressions or wildcards (if enabled in calculation options).

Range2 - Opsional. Range2 dan semua yang berikut memiliki arti yang sama dengan Range1.

Criterion2 – Optional. Criterion2 and all the following mean the same as Criterion.

The search supports wildcards or regular expressions. With regular expressions enabled, you can enter "all.*", for example to find the first location of "all" followed by any characters. If you want to search for a text that is also a regular expression, you must either precede every character with a "\" character, or enclose the text into \Q...\E. You can switch the automatic evaluation of wildcards or regular expression on and off in LibreOffice - PreferencesTools - Options - LibreOffice Calc - Calculate.

When using functions where one or more arguments are search criteria strings that represents a regular expression, the first attempt is to convert the string criteria to numbers. For example, ".0" will convert to 0.0 and so on. If successful, the match will not be a regular expression match but a numeric match. However, when switching to a locale where the decimal separator is not the dot makes the regular expression conversion work. To force the evaluation of the regular expression instead of a numeric expression, use some expression that can not be misread as numeric, such as ".[0]" or ".\0" or "(?i).0".

Func_Range dan Range1, Range2 ... harus memiliki ukuran yang sama, jika tidak fungsi mengembalikan err: 502 - Argumen tidak valid.

Hubungan logis antara kriteria dapat didefinisikan sebagai logika AND (kata hubung). Dengan kata lain, jika dan hanya jika semua kriteria yang diberikan terpenuhi, nilai dari sel yang sesuai dari Func_Range yang diberikan diperhitungkan.

Fungsi ini dapat memiliki hingga 255 argumen, artinya Anda dapat menentukan 127 rentang kriteria dan kriteria untuknya.

Jika sel berisi TRUE, itu diperlakukan sebagai 1, jika sel berisi FALSE - sebagai 0 (nol).

Fungsi ini adalah bagian dari Open Document Format untuk Aplikasi Perkantoran (OpenDocument) Versi 1.2. (ISO/IEC 26300:2-2015)

#### Contoh

Pertimbangkan tabel berikut

| A | B | C
1 | Nama Produk | Penjualan | Pendapatan
2 | pensil | 20 | 65
3 | pena | 35 | 85
4 | buku catatan | 20 | 190
5 | buku | 17 | 180
6 | kotak pensil | tidak | tidak

Dalam semua contoh di bawah ini, rentang untuk perhitungan mengandung baris #6, yang diabaikan karena mengandung teks.

#### Penggunaan sederhana

=MAXIFS(B2:B6;B2:B6;"<35")

Menghitung nilai maksimum dari rentang B2:B6 yang lebih besar dari atau sama dengan 20. Pengembalian 35. Baris kelima tidak memenuhi kriteria.

=MAXIFS(C2:C6;B2:B6;">=20";C2:C6;"<90")

Menghitung nilai maksimum rentang C2:C6 yang lebih rendah dari 90 dan sesuai dengan sel rentang B2:B6 dengan nilai lebih besar dari atau sama dengan 20. Mengembalikan 85, karena baris keempat dan kelima tidak memenuhi setidaknya satu kriteria.

#### Menggunakan ekspresi reguler dan fungsi bersarang

=MAXIFS(C2:C6;B2:B6;">"&MIN(B2:B6);B2:B6;"<"&MAX(B2:B6))

Menghitung nilai maksimum rentang C2:C6 yang sesuai dengan semua nilai rentang B2:B6 kecuali minimum dan maksimum. Mengembalikan 190, karena hanya baris keempat yang memenuhi kriteria.

=MAXIFS(C2:C6;A2:A6;"pen.*";B2:B6;"<="&MAX(B2:B6))

Menghitung nilai maksimum rentang C2:C6 yang sesuai dengan semua sel rentang A2:A6 yang dimulai dengan "pena" dan ke semua sel rentang B2:B6 kecuali maksimumnya. Mengembalikan 85, karena hanya baris ketiga yang memenuhi semua kriteria.

#### Referensi ke sel sebagai kriteria

Jika Anda perlu mengubah kriteria dengan mudah, Anda mungkin ingin menentukannya di sel yang terpisah dan menggunakan referensi ke sel ini dalam kondisi fungsi MAXIFS. Misalnya, fungsi di atas dapat ditulis ulang sebagai berikut:

=MAXIFS(C2:C6;A2:A6;E2&".*";B2:B6;"<"&MAX(B2:B6))

If E2 = "pena", fungsi mengembalikan 65, karena referensi ke sel diganti dengan kontennya.

#### Technical information

Fungsi ini tersedia sejak LibreOffice 5.2.

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

COM.MICROSOFT.MAXIFS

Topik Terkait

MAX, MAXA, MIN, MINA,

COUNTIFS, MINIFS, fungsi MAXIFS, AVERAGEIFS, SUMIFS

Daftar Ekspresi Reguler