Innhold
Innholdsliste 🔎︎

# Regnearksfunksjoner

This section contains descriptions of the Spreadsheet functions together with an example.

For å bruke denne funksjonen …

Sett inn → Funksjon → Kategori Regneark

## FEIL.TYPE

Returns a number representing a specific Error type, or the error value #N/A, if there is no error.

## ADDRESSE (ADDRESS på engelsk)

Gir en celleadresse (referanse) som tekst, i følge de oppgitte rad- og kolonnenumrene. Du kan finne ut om adressen er tolket som en absolutt adresse (for eksempel $A$1), relativ adresse (A1) eller i blandet form (A$1 eller $A1). Du kan også angi navnet til regnearket.

Av hensyn til interoperabilitet støtter funksjonene ADRESSE og INDIREKTE (INDIRECT på engelsk) en valgfri parameter for å angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT på engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, så blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, så blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT på engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

When storing a document in ODF 1.0/1.1 format, if ADDRESS functions have a fourth parameter, that parameter will be removed.

Do not save a spreadsheet in the old ODF 1.0/1.1 format if the ADDRESS function's new fourth parameter was used with a value of 0.

The INDIRECT function is saved without conversion to ODF 1.0/1.1 format. If the second parameter was present, an older version of Calc will return an error for that function.

#### Syntax

ADDRESS(Row; Column [; Abs [; A1 [; "Sheet"]]])

Rad tilsvarer radnummeret for cellereferansen

Kolonne tilsvarer kolonnenummeret for cellereferansen (tallet, ikke bokstaven)

ABS bestemmer typen av referanse:

1: absolutt ($A$1)

2: radreferansetype er absolutt; kolonnereferanse er relativ (A$1)

3: rad (relativ); kolonne (absolutt) ($A1)

4: relativ (A1)

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

Ark tilsvarer navnet på arket. Det kan være plassert i dobbelt hermetegn.

### Eksempel:

=ADDRESS(1;1;2;;"Sheet2") returns the following: Sheet2.A$1

If the formula above is in cell B2 of current sheet, and the cell A1 in sheet 2 contains the value -6, you can refer indirectly to the referenced cell using a function in B2 by entering =ABS(INDIRECT(B2)). The result is the absolute value of the cell reference specified in B2, which in this case is 6.

## ANTALL.ARK (SHEETS på engelsk)

Finn antall ark i en referanse. Hvis du ikke angir noen parametere gir funksjonen antall ark i dette dokumentet.

#### Syntax

SHEETS([Reference])

Referanse er referansen til et ark eller et område. Denne parameteren er valgfri.

#### Example

=ANTALL.ARK(Ark1.A1:Ark3.G12) gir 3, hvis Ark1, Ark2 og Ark3 finnes i den angitte rekkefølgen.

## DDE

Gir resultatet av en DDE-basert lenke. Hvis innholdet i det lenkede området endres, vil også resultatet endres. Du må laste regnearket på nytt eller velge Rediger – Lenker for å se de oppdaterte lenkene. Det er ikke tillatt med lenker fra en plattform til en annen, for eksempel fra en installasjon av LibreOffice på en Windows-maskin til et dokument opprettet på en Linux-maskin.

#### Syntax

DDE("Server"; "File"; "Range" [; Mode])

Server is the name of a server application. LibreOffice applications have the server name "soffice".

Fil er det fullstendige filnavnet med sti oppgitt.

Område er området som inneholder dataen som skal valideres.

Modus er en valgfri parameter som bestemmer den metoden som DDE-tjeneren bruker for å gjøre om sine data til tall.

Navn | Forskyvning
0 eller manglende | Tallformat fra cellestilten «Standard»
1 | Data blir alltid fortolket som standard US engelsk-format.
2 | Data blir hentet som tekst; ingen omgjøring til tall.

#### Example

=DDE("soffice";"c:\office\document\data1.ods";"sheet1.A1") reads the contents of cell A1 in sheet1 of the LibreOffice Calc spreadsheet data1.ods.

=DDE("soffice";"c:\office\document\motto.odt";"Today's motto") returns a motto in the cell containing this formula. First, you must enter a line in the motto.odt document containing the motto text and define it as the first line of a section named Today's Motto (in LibreOffice Writer under Insert - Section). If the motto is modified (and saved) in the LibreOffice Writer document, the motto is updated in all LibreOffice Calc cells in which this DDE link is defined.

## FEILTYPE (ERRORTYPE på engelsk)

Returns the number corresponding to an error value occurring in a different cell. With the aid of this number, you can generate an error message text.

Dersom det oppstår en feil, vil funksjonen gi en logisk eller numerisk verdi.

The Status Bar displays the predefined error code from LibreOffice if you click the cell containing the error.

#### Syntax

FEILTYPE(Referanse)

Referanse inneholder adressen på den cellen som feilen oppstår i.

#### Example

Hvis celle A1 viser Err:518, gir funksjonen =FEILTYPE(A1) tallet 518.

#### Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.ERRORTYPE

## FINN.KOLONNE (HLOOKUP på engelsk)

Søker etter en verdi og en referanse til cellene nedenfor det merkede området. Funksjonen sjekker om den første raden i en tabell inneholder en viss verdi. Funksjonen gir så verdien i en rad i tabellen, angitt av Indeks, i den samme kolonnen.

Søket støtter jokertegn eller regular expressions. Med regulære uttrykk aktivert , kan du skrive "alle.*", for eksempel for å finne den første forekomsten av "alle" fulgt av villkårlge tegn. Hvis du vil søke etter en tekst som også er et vanlig uttrykk, må du enten foran hvert tegn med et "\" -tegn, eller vedlegge teksten til \ Q ... \ E. Du kan slå automatisk evaluering av jokertegn eller vanlig uttrykk av og på i LibreOffice - EgenskaperVerktøy - Alternativer - LibreOffice Calc - Kalkuler.

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntax

HLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

For an explanation on the parameters, see: VLOOKUP (columns and rows are exchanged)

Håndtering av tomme celler

#### Example

Suppose we have built a small database table occupying the cell range A1:DO4 and containing basic information about 118 chemical elements. The first column contains the row headings “Element”, “Symbol”, “Atomic Number”, and “Relative Atomic Mass”. Subsequent columns contain the relevant information for each of the elements, ordered left to right by atomic number. For example, cells B1:B4 contain “Hydrogen”, “H”, “1” and “1.008”, while cells DO1:DO4 contain “Oganesson”, “Og”, “118”, and “294”.

| A | B | C | D | ... | DO
--- | --- | --- | --- | --- | --- | ---
1 | Element | Hydrogen | Helium | Lithium | ... | Oganesson
2 | Symbol | H | He | Li | ... | Og
3 | Atomic Number | 1 | 2 | 3 | ... | 118
4 | Relative Atomic Mass | 1.008 | 4.0026 | 6.94 | ... | 294

=HLOOKUP("Lead"; $A$1:$DO$4; 2; 0) returns “Pb”, the symbol for lead.

=HLOOKUP("Gold"; $A$1:$DO$4; 3; 0) returns 79, the atomic number for gold.

=HLOOKUP("Carbon"; $A$1:$DO$4; 4; 0) returns 12.011, the relative atomic mass of carbon.

## FINN.NÅ (LOOKUP på engelsk)

Returns the contents of a cell either from a one-row or one-column range. Optionally, the assigned value (of the same index) is returned in a different column and row. As opposed to VLOOKUP and HLOOKUP, search and result vector may be at different positions; they do not have to be adjacent. Additionally, the search vector for the LOOKUP must be sorted ascending, otherwise the search will not return any usable results.

Hvis FINN.NÅ (LOOKUP på engelsk) ikke kan finne søkekriteriet, benyttes den største verdien i søkeretningen som er mindre enn eller lik søkekriteriet.

Søket støtter jokertegn eller regular expressions. Med regulære uttrykk aktivert , kan du skrive "alle.*", for eksempel for å finne den første forekomsten av "alle" fulgt av villkårlge tegn. Hvis du vil søke etter en tekst som også er et vanlig uttrykk, må du enten foran hvert tegn med et "\" -tegn, eller vedlegge teksten til \ Q ... \ E. Du kan slå automatisk evaluering av jokertegn eller vanlig uttrykk av og på i LibreOffice - EgenskaperVerktøy - Alternativer - LibreOffice Calc - Kalkuler.

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntax

LOOKUP(Lookup; SearchVector [; ResultVector])

Lookup is the value of any type to be looked for; entered either directly or as a reference.

SearchVector is the single-row or single-column area to be searched.

ResultVector is another single-row or single-column range from which the result of the function is taken. The result is the cell of the result vector with the same index as the instance found in the search vector.

Håndtering av tomme celler

#### Example

=LOOKUP(A1;D1:D100;F1:F100) searches the corresponding cell in range D1:D100 for the number you entered in A1. For the instance found, the index is determined, for example, the 12th cell in this range. Then, the contents of the 12th cell are returned as the value of the function (in the result vector).

## FINN.RAD (VLOOKUP på engelsk)

Vertical search with reference to adjacent cells to the right. This function checks if a specific value is contained in the first column of an array. The function then returns the value in the same row of the column named by Index. If the Sorted parameter is omitted or set to TRUE or one, it is assumed that the data is sorted in ascending order. In this case, if the exact Lookup is not found, the last value that is smaller than the criterion will be returned. If Sorted is set to FALSE or zero, an exact match must be found, otherwise the error Error: Value Not Available will be the result. Thus with a value of zero the data does not need to be sorted in ascending order.

Søket støtter jokertegn eller regular expressions. Med regulære uttrykk aktivert , kan du skrive "alle.*", for eksempel for å finne den første forekomsten av "alle" fulgt av villkårlge tegn. Hvis du vil søke etter en tekst som også er et vanlig uttrykk, må du enten foran hvert tegn med et "\" -tegn, eller vedlegge teksten til \ Q ... \ E. Du kan slå automatisk evaluering av jokertegn eller vanlig uttrykk av og på i LibreOffice - EgenskaperVerktøy - Alternativer - LibreOffice Calc - Kalkuler.

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Syntax

=VLOOKUP(Lookup; Array; Index [; SortedRangeLookup])

Lookup is the value of any type looked for in the first column of the array.

Array is the reference, which is to comprise at least as many columns as the number passed in Index argument.

Indeks er kolonnenummeret i området som inneholder verdien som skal returneres. Den første kolonnen har tallet 1.

SortedRangeLookup is an optional parameter that indicates whether the first column in the array contains range boundaries instead of plain values. In this mode, the lookup returns the value in the row with first column having value equal to or less than Lookup. E.g., it could contain dates when some tax value had been changed, and so the values represent starting dates of a period when a specific tax value was effective. Thus, searching for a date that is absent in the first array column, but falls between some existing boundary dates, would give the lower of them, allowing to find out the data being effective to the searched date. Enter the Boolean value FALSE or zero if the first column is not a range boundary list. When this parameter is TRUE or not given, the first column in the array must be sorted in ascending order. Sorted columns can be searched much faster and the function always returns a value, even if the search value was not matched exactly, if it is greater than the lowest value of the sorted list. In unsorted lists, the search value must be matched exactly. Otherwise the function will return #N/A with message: Error: Value Not Available.

Håndtering av tomme celler

#### Example

You want to enter the number of a dish on the menu in cell A1, and the name of the dish is to appear as text in the neighboring cell (B1) immediately. The Number to Name assignment is contained in the D1:E100 array. D1 contains 100, E1 contains the name Vegetable Soup, and so forth, for 100 menu items. The numbers in column D are sorted in ascending order; thus, the optional Sorted parameter is not necessary.

Skriv inn følgende formel i B1:

=FINN.RAD(A1; D1:E100; 2)

As soon as you enter a number in A1 B1 will show the corresponding text contained in the second column of reference D1:E100. Entering a nonexistent number displays the text with the next number down. To prevent this, enter FALSE as the last parameter in the formula so that an error message is generated when a nonexistent number is entered.

## FORSKYVNING (OFFSET på engelsk)

Gir verdien til en celle som ligger et visst antall rader og kolonner fra et gitt referansepunkt.

This function is always recalculated whenever a recalculation occurs.

#### Syntax

OFFSET(Reference; Rows; Columns [; Height [; Width]])

Referanse er cellen hvorfra funksjonen leter etter den nye referansen.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

Rader er antall rader referansen ble korrigert oppover (negativ verdi) eller ned.

Høyde (valgfri) er den valgfrie loddrette høyden på et område som begynner ved den nye referanseposisjonen.

Bredde (valgfri) er den vannrette bredden for et område som begynner ved den nye referanseposisjonen.

Argumentene Høyde og Bredde kan ikke føre til null eller et negativt antall av rader eller kolonner.

Argumentene Høyde og Bredde kan ikke føre til null eller et negativt antall av rader eller kolonner.

I LibreOffice Calc-funksjoner kan parametre merket som «valgfri» kun utelates hvis ingen parameter følger etter. For eksempel i en funksjon med fire parametre, hvor de siste to parametrene er merket som «valgfri», kan du utelade parameter 4 eller parametrene 3 og 4, men du kan ikke utelate parameter 3 alene.

#### Example

=FORSKYVNING(A1; 2; 2) gir verdien i celle C3 (A1 flyttet med to rader og to kolonner nedover). Hvis C3 inneholder verdien 100 gir denne funksjonen verdien 100.

=FORSKYVNING(B2:C3;1;1) gir en referanse til B2:C3 flyttet 1 rad ned og en kolonne til høyre (C3:D4).

=FORSKYVNING(B2:C3;-1;-1) gir en referanse til B2:C3 flyttet 1 rad opp og en kolonne til venstre (A1:B2).

=FORSKYVNING(B2:C3;0;0;3;4) gir en referanse til B2:C3 med størrelsen endret til 3 rader og 4 kolonner (B2:E4).

=FORSKYVNING(B2:C3;1;0;3;4) gir en referanse til B2:C3 flyttet en rad ned og med størrelsen endret til 3 rader og 4 kolonner (B2:E4).

=SUMMER(FORSKYVNING(A1;2;2;5;6)) bestemmer summen av området som starter i celle C3 og har en høyde på 5 rader og en bredde av 6 kolonner (område=C3:H7).

If Width or Height are given, the OFFSET function returns a cell range reference. If Reference is a single cell reference and both Width and Height are omitted, a single cell reference is returned.

## HENTPIVOTDATA

The GETPIVOTDATA function returns a result value from a pivot table. The value is addressed using field and item names, so it remains valid if the layout of the pivot table changes.

#### Syntax

To forskjellige syntaksdefinisjoner kan brukes:

GETPIVOTDATA(TargetField; pivot table[; Field 1; Item 1][; ... [Field 126; Item 126]])

or

GETPIVOTDATA(pivot table; Constraints)

Syntaks nr. 2 antas å være brukt hvis eksakt to parametre er gitt, hvor den første parameteren er en referanse til en celle eller et celleområde. Det første syntaks antas å være brukt i alle andre tilfeller. Funksjonsveiviseren viser det første syntaks.

### First Syntax

TargetField is a string that selects one of the pivot table's data fields. The string can be the name of the source column, or the data field name as shown in the table (like "Sum - Sales").

pivot table is a reference to a cell or cell range that is positioned within a pivot table or contains a pivot table. If the cell range contains several pivot tables, the table that was created last is used.

If no Field n / Item n pairs are given, the grand total is returned. Otherwise, each pair adds a constraint that the result must satisfy. Field n is the name of a field from the pivot table. Item n is the name of an item from that field.

If the pivot table contains only a single result value that fulfills all of the constraints, or a subtotal result that summarizes all matching values, that result is returned. If there is no matching result, or several ones without a subtotal for them, an error is returned. These conditions apply to results that are included in the pivot table.

If the source data contains entries that are hidden by settings of the pivot table, they are ignored. The order of the Field/Item pairs is not significant. Field and item names are not case-sensitive.

If no constraint for a filter is given, the field's selected value is implicitly used. If a constraint for a filter is given, it must match the field's selected value, or an error is returned. Filters are the fields at the top left of a pivot table, populated using the "Filters" area of the pivot table layout dialog. From each filter, an item (value) can be selected, which means only that item is included in the calculation.

Subtotal values from the pivot table are only used if they use the function "auto" (except when specified in the constraint, see Second Syntax below).

### Second Syntax

pivot table has the same meaning as in the first syntax.

Constraints is a space-separated list. Entries can be quoted (single quotes). The whole string must be enclosed in quotes (double quotes), unless you reference the string from another cell.

One of the entries can be the data field name. The data field name can be left out if the pivot table contains only one data field, otherwise it must be present.

Each of the other entries specifies a constraint in the form Field[Item] (with literal characters [ and ]), or only Item if the item name is unique within all fields that are used in the pivot table.

Et funksjonsnavn kan legges til på formen felt[element;funksjon], hvilket betyr at kriteriene bare passer på delsumverdier som bruker denne funksjonen. De mulige funksjonsnavnene er Summer, Antall, Middel, Maks, Min, Produkt, Antall (kun tall), Stdav, Stdavp, Varians, og Variansp. Det skille ikke mellom store og små bokstaver.

## HYPERLENKE

Når du trykker på en celle som inneholder HYPERLENKE-funksjonen vil hypelenken åpnes.

If you use the optional CellValue parameter, the formula locates the URL, and then displays the text or number.

For å åpne en hyperlenken celle med tastaturet, velg cellen, trykk «F2» for å gå i redigeringsmodus, flytt pekeren foran hyperlenken, trykke «Shift+F10» og velg såÅpne hyperlenke.

#### Syntax

HYPERLINK("URL" [; CellValue])

URL specifies the link target. The optional CellValue parameter is the text or a number that is displayed in the cell and will be returned as the result. If the CellValue parameter is not specified, the URL is displayed in the cell text and will be returned as the result.

The number 0 is returned for empty cells and matrix elements.

#### Example

=HYPERLINK("http://www.example.org") displays the text "http://www.example.org" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";"Click here") displays the text "Click here" in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("http://www.example.org";12345) displays the number 12345 and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK($B4) where cell B4 contains http://www.example.org. The function adds http://www.example.org to the URL of the hyperlink cell and returns the same text which is used as formula result.

=HYPERLINK("http://www.";"Click ") & "example.org" displays the text Click example.org in the cell and executes the hyperlink http://www.example.org when clicked.

=HYPERLINK("#Sheet1.A1";"Go to top") displays the text Go to top and jumps to cell Sheet1.A1 in this document.

=HYPERLINK("file:///C:/writer.odt#Specification";"Go to Writer bookmark") displays the text "Go to Writer bookmark", loads the specified text document and jumps to bookmark "Specification".

=HYPERLINK("file:///C:/Documents/";"Open Documents folder") displays the text "Open Documents folder" and shows the folder contents using the standard file manager in your operating system.

## INDEKS (INDEX på engelsk)

INDEKS gir innholdet av en celle, angitt enten ved rad og kolonne eller ved et navngitt område. Avhengig av sammenhengen gir INDEKS enten innhold eller en referanse.

#### Syntax

INDEX(Reference [; Row [; Column [; Range]]])

Referanse er en cellereferanse, enten skrevet inn direkte eller ved å bruke navnet på et område. Hvis referansen består av flere områder, må du angi referansen eller områdenavnet i parentes.

Rad (valgfri) representerer radnummeret til referanseområdet som skal returneres som en verdi. Hvis null (ingen spesifikk rad) returneres alle refererte rader

Kolonne (valgfri) representerer kolonnenummeret til referanseområdet som skal returneres som en verdi. Hvis null (ingen spesifikk kolonne) returneres alle refererte kolonner.

Område (valgfri) tilsvarer indeksen for underområdet som refererer til flere områder.

#### Example

=INDEKS(Priser;4;1) gir verdien fra rad 4 og kolonne 1 av databaseområdet angitt i Data → Angi som Priser.

=INDEX(SumX;4;1) returns the value from the range SumX in row 4 and column 1 as defined in Sheet - Named Ranges and Expressions - Define.

=INDEKS(A1:B6;1) gir en referanse til den første raden i A1:B6.

=INDEKS(A1:B6;0;1) gir en referanse til den første kolonnen i A1:B6.

=INDEX((multi);4;1) indicates the value contained in row 4 and column 1 of the (multiple) range, which you named under Sheet - Named Ranges and Expressions - Define as multi. The multiple range may consist of several rectangular ranges, each with a row 4 and column 1. If you now want to call the second block of this multiple range enter the number 2 as the range parameter.

=INDEKS(A1:B6;1;1) angir verdien øverst i det venstre hjørnet av området A1:B6.

=INDEKS((multi);0;0;2) gir en referanse til det andre området av multiområdet.

## INDIREKTE (INDIRECT på engelsk)

Gir referansen som er angitt ved en tekststreng. Du kan også bruke denne funksjonen for å finne området til den samsvarende strengen.

This function is always recalculated whenever a recalculation occurs.

Av hensyn til interoperabilitet støtter funksjonene ADRESSE og INDIREKTE (INDIRECT på engelsk) en valgfri parameter for å angi om R1C1 adresse-notasjonen kan brukes i stedet for den vanlige A1-notasjonen.

I ADRESSE, blir parameteren satt inn som den fjerde parameteren, som flytter den valgfrie arknavn-parameteren til den femte plassering.

I INDIREKTE (INDIRECT på engelsk), er parameteren lagt til som den andre parameteren.

I begge funksjoner gjelder det, at hvis argumentet blir satt inn med verdien 0, så blir R1C1-notasjonen brukt. Hvis argumentet ikke er gitt eller har en annen verdi enn 0, så blir A1-notasjonen brukt.

I tilfelle av R1C1-notasjon, gir ADRESSE strenger som bruker utropstegn '!' som skilletegn for arkets navn, da INDIREKTE (INDIRECT på engelsk) forventer utropstegnet som skilletegn for arknavn. Begge funksjonene bruker fortsatt punktum '.' som skilletegn for arknavn med A1-notasjon.

When opening documents from ODF 1.0/1.1 format, the ADDRESS functions that show a sheet name as the fourth parameter will shift that sheet name to become the fifth parameter. A new fourth parameter with the value 1 will be inserted.

When storing a document in ODF 1.0/1.1 format, if ADDRESS functions have a fourth parameter, that parameter will be removed.

Do not save a spreadsheet in the old ODF 1.0/1.1 format if the ADDRESS function's new fourth parameter was used with a value of 0.

The INDIRECT function is saved without conversion to ODF 1.0/1.1 format. If the second parameter was present, an older version of Calc will return an error for that function.

#### Syntax

INDIRECT(Ref [; A1])

Referanse tilsvarer en referanse til en celle eller et område (i tekstform) som verdien skal returneres fra.

A1 (valgfri) — hvis satt til 0, blir notasjonen R1C1 brukt. Hvis parameteren mangler eller er satt til en annen verdi enn 0, blir notasjonen A1 brukt.

If you open an Excel spreadsheet that uses indirect addresses calculated from string functions, the sheet addresses will not be translated automatically. For example, the Excel address in INDIRECT("[filename]sheetname!"&B1) is not converted into the Calc address in INDIRECT("filename#sheetname."&B1).

#### Example

=INDIREKTE(A1) er lik 100 hvis A1 inneholder C108 som en referanse og celle C108 inneholder en verdi på 100.

=SUMMER(INDIREKTE("A1:" & ADRESSE(1;3))) summerer cellene i området fra A1 opp til cellen hvis adresse er angitt ved rad 1 og kolonne 3. Det vil si: A1:C1 er oppsummert.

## KOLONNE (COLUMN på engelsk)

Returns the column number of a cell reference. If the reference is a cell the column number of the cell is returned; if the parameter is a cell area, the corresponding column numbers are returned in a single-row array if the formula is entered as an array formula. If the COLUMN function with an area reference parameter is not used for an array formula, only the column number of the first cell within the area is determined.

#### Syntax

COLUMN([Reference])

Referanse er referansen til en celle eller celleområde hvis første kolonnenummer finnes.

Hvis ingen referanse skrives inn, blir kolonnenummeret for cellen hvor formelen er skrevet inn funnet.LibreOffice Calc angir automatisk henvisningen til den gjeldende cellen.

#### Example

=KOLONNE(A1) er lik 1. Kolonne A er den første kolonnen i tabellen.

=KOLONNE(C3:E3) er lik 3. Kolonne C er den tredje kolonnen i tabellen.

=KOLONNE(D3:G10) gir 4, fordi kolonne D er den fjerde kolonnen i tabellen, og KOLONNE-funksjonen ikke er brukt som en matriseformel. (I dette tilfellet brukes den første verdien i matrisen alltid som resultat.)

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver især 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneområder bare har et kolonnenummer, gjør det ingen forskjell om formelen blir brukt som en matriseformel.

==KOLONNE() gir 3 hvis formelen ble skrevet inn i kolonne C.

{=KOLONNE(Kanin)} gir enkeltradmatrisen (3; 4) hvis "Kanin" er det navngitte området (C1:D3).

## KOLONNER (COLUMNS på engelsk)

Gir antall kolonner i den oppgitte referansen.

#### Syntax

KOLONNER(Matrise)

Array is the reference to a cell range whose total number of columns is to be found. The argument can also be a single cell.

#### Example

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=KOLONNER(A1:C5) er lik 3. Henvisningen omfatter tre Kolonner.

=KOLONNER(Kanin) gir 2 hvisKanin er det navngitte området (C1:D3).

## OMRÅDER (AREAS på engelsk)

Gir antall individuelle områder som er med i et sammensatt område. Et dataområde kan bestå av èn enkelcelle eller et sammenhengende celleområde.

The function expects a single argument. If you state multiple ranges, you must enclose them into additional parentheses. Multiple ranges can be entered using the semicolon (;) as divider, but this gets automatically converted to the tilde (~) operator. The tilde is used to join ranges.

#### Syntax

OMRÅDER(Referanse)

Referanse representerer referansen til en celle eller et celleområde.

#### Example

=AREAS((A1:B3;F2;G1)) returns 3, as it is a reference to three cells and/or areas. After entry this gets converted to =AREAS((A1:B3~F2~G1)).

=OMRÅDER(Alt) gir 1 hvis du har angitt et område ved navn «Alt» under Data → Angi område..

## RAD

Returns the row number of a cell reference. If the reference is a cell, it returns the row number of the cell. If the reference is a cell range, it returns the corresponding row numbers in a one-column Array if the formula is entered as an array formula. If the ROW function with a range reference is not used in an array formula, only the row number of the first range cell will be returned.

#### Syntax

ROW([Reference])

Referanse er en celle, et område eller navnet på et område.

Hvis du ikke angir en referanse, vil radnummeret for cellen hvor formlen er skrevet inn bli funnet.LibreOffice Calc angir automatisk referansen til den gjeldende cellen.

#### Example

RAD(B3) gir 3, fordi referansen henviser til den tredje raden i tabellen.

{=RAD(D5:D8)} gir matrisen med enkeltkolonnen (5, 6, 7, 8), fordi den angitte referansen inneholder radene 5 til 8.

=RAD(D5:D8) gir 5 fordi REKKE-funksjonen ikke blir brukt som matriseformel og bare nummeret på den første raden i referansen returneres.

{=KOLONNE(B2:B7)} og =KOLONNE(B2:B7) gir hver især 2 fordi referansen bare inneholder kolonne B som den annen kolonne i tabellen. Fordi enkelt-kolonneområder bare har et kolonnenummer, gjør det ingen forskjell om formelen blir brukt som en matriseformel.

=RAD() gir 3 hvis formelen ble skrevet inn i rad 3.

{=RAD(Kanin)} gir matrisen med enkeltkolonnen (1, 2, 3) hvis "Kanin" er det navngitte området (C1:D3).

## RADER (ROWS på engelsk)

Gir antall rader i en referanse eller tabell.

#### Syntax

RADER(Matrise)

Matrise er referansen eller det navngitte området som totale antall rader skal oppdages for.

#### Example

=Rader(B5) gir 1, fordi en celle inneholder kun en enkelt rad.

=RADER(A10:B12) gir 3.

=RADER(Kanin) gir 3, hvis "Kanin" er det navngitte området (C1:D3).

## SAMMENLIGNE (MATCH på engelsk)

Gir den relative posisjonen til et element i en tabell, der elementet svarer til en viss verdi. Funksjonen gir posisjonen, som et nummer, til verdien funnet i søketabellen.

#### Syntax

MATCH(Search; LookupArray [; Type])

Search is the value which is to be searched for in the single-row or single-column array.

LookupArray is the reference searched. A lookup array can be a single row or column, or part of a single row or column.

Type may take the values 1, 0, or -1. If Type = 1 or if this optional parameter is missing, it is assumed that the first column of the search array is sorted in ascending order. If Type = -1 it is assumed that the column in sorted in descending order. This corresponds to the same function in Microsoft Excel.

If Type = 0, only exact matches are found. If the search criterion is found more than once, the function returns the index of the first matching value. Only if Type = 0 can you search for regular expressions (if enabled in calculation options) or wildcards (if enabled in calculation options).

If Type = 1 or the third parameter is missing, the index of the last value that is smaller or equal to the search criterion is returned. For Type = -1, the index of the last value that is larger or equal is returned.

Søket støtter jokertegn eller regular expressions. Med regulære uttrykk aktivert , kan du skrive "alle.*", for eksempel for å finne den første forekomsten av "alle" fulgt av villkårlge tegn. Hvis du vil søke etter en tekst som også er et vanlig uttrykk, må du enten foran hvert tegn med et "\" -tegn, eller vedlegge teksten til \ Q ... \ E. Du kan slå automatisk evaluering av jokertegn eller vanlig uttrykk av og på i LibreOffice - EgenskaperVerktøy - Alternativer - LibreOffice Calc - Kalkuler.

Når du bruker funksjoner der ett eller flere argumenter er søkekriterier, som representerer et regulært uttrykk, er det første forsøket å konvertere strengkriteriene til tall. For eksempel vil ".0" konverteres til 0.0 og så videre. Hvis det lykkes, vil matchingen ikke være et vanlig uttrykk, men en numerisk match. Imidlertid, når du bytter til et sted der desimalskilleren ikke er punktum, får det konvertering av regulære uttrykk å fungere. For å tvinge evalueringen av det regulære uttrykket i stedet for et numerisk uttrykk, bruker du et uttrykk som ikke kan feilleses som numerisk, for eksempel ". [0]" eller ". \ 0" eller "(? I) .0".

#### Example

=MATCH(200;D1:D100) searches the area D1:D100, which is sorted by column D, for the value 200. As soon as this value is reached, the number of the row in which it was found is returned. If a higher value is found during the search in the column, the number of the previous row is returned.

## SHEET

Returns the sheet number of either a reference or a string representing a sheet name. If you do not enter any parameters, the result is the sheet number of the spreadsheet containing the formula.

#### Syntax

SHEET([Reference])

Referanse er valgfri og er referansen til en celle, et område eller et arknavn.

#### Example

=SHEET(Sheet2.A1) returns 2 if Sheet2 is the second sheet in the spreadsheet document.

=SHEET("Sheet3") returns 3 if Sheet3 is the third sheet in the spreadsheet document.

## STIL (STYLE på engelsk)

Applies a style to the cell containing the formula. After a set amount of time, another style can be applied. This function always returns the value 0, allowing you to add it to another function without changing the value. Together with the CURRENT function you can apply a color to a cell depending on the value. For example: =...+STYLE(IF(CURRENT()>3;"red";"green")) applies the style "red" to the cell if the value is greater than 3, otherwise the style "green" is applied. Both cell formats, "red" and "green" have to be defined beforehand.

#### Syntax

STYLE("Style" [; Time [; "Style2"]])

Stil er navnet på en cellestil tildelt cellen. Stilnavn må tastes inn i hermetegn.

Tid er en valgfri tidsperiode i sekunder. Hvis denne parameteren mangler, vil ikke stilen bli endret etter et bestemt tidsrom.

Stil2 er den valgfrie cellestilen tildelt cellen etter et bestemt tidsrom. Hvis denne parameteren mangler vil "Standard" bli benyttet.

I LibreOffice Calc-funksjoner kan parametre merket som «valgfri» kun utelates hvis ingen parameter følger etter. For eksempel i en funksjon med fire parametre, hvor de siste to parametrene er merket som «valgfri», kan du utelade parameter 4 eller parametrene 3 og 4, men du kan ikke utelate parameter 3 alene.

#### Example

=STIL("Usynlig";60;"Standard") formaterer cellen i gjennomsiktig format i 60 sekunder etter dokumentet ble omberegnet (eller lest inn), deretter vil standardformat bli brukt. Begge celleformatene må være angitt på forhånd.

Since STYLE() has a numeric return value of zero, this return value gets appended to a string. This can be avoided using T() as in the following example:

="Tekst"&T(STIL"minStil"))

Se også GJELDENDE() for et annet eksempel.

#### Technical information

This function is not part of the Open Document Format for Office Applications (OpenDocument) Version 1.3. Part 4: Recalculated Formula (OpenFormula) Format standard. The name space is

ORG.OPENOFFICE.STYLE

## VELG (CHOOSE på engelsk)

Bruker en indeks for å hente en verdi fra en liste med opptil 30 verdier.

#### Syntax

CHOOSE(Index; Value 1 [; Value 2 [; ... [; Value 30]]])

Indeks er en referanse eller et tall mellom 1 og 30, som angir hvilke verdier som skal tas fra listen.

Value 1, Value 2, ..., Value 30 is the list of values entered as a reference to a cell or as individual values.

#### Example

=VELG(A1; B1; B2; B3; "I dag"; "I går"; "I morgen"), gir for eksempel innholdet av celle B2 til A1 = 2; for A1 = 4 vil funksjonen returnere teksten "I dag".

Lignende emner

Funksjoner etter kategori