Conteúdo
Índice 🔎︎

# Funções de banco de dados

### Visão geral

As doze funções na categoria Banco de dados ajudam você a analisar um banco de dados simples que ocupa uma área retangular da planilha composta por colunas e linhas, com os dados organizados como uma linha para cada registro. A célula de cabeçalho de cada coluna exibe o nome da coluna e esse nome geralmente reflete o conteúdo de cada célula dessa coluna.

As funções na categoria Banco de dados aceitam três argumentos, a seguir:

1. BancodeDados. O intervalo de células do banco de dados.

2. CampoBancodeDados. A coluna contendo os dados a serem utilizados no cálculo das funções.

3. CritérioPesquisa. O intervalo de células de uma área separada da planilha contendo o critério de pesquisa.

Estes argumentos são descritos em detalhe abaixo.

Todas as funções têm o mesmo conceito básico de operação. A primeira etapa lógica é usar o CriterioPesquisa especificado para identificar o subconjunto de registros no BancodeDados que deve ser usado durante os cálculos subsequentes. A segunda etapa é extrair os valores dos dados e realizar os cálculos associados à função específica (média, soma, produto e assim por diante). Os valores processados são aqueles na coluna CampoBancodeDados dos registros selecionados.

O Calc trata datas e valores lógicos (VERDADEIRO e FALSO) como números ao calcular com essas funções.

### Argumentos das funções de banco de dados

Os seguintes argumentos se aplicam a todas as funções na categoria Banco de dados:

1. Argumento BancodeDados

   BancodeDados especifica o intervalo de células ocupadas pela tabela do banco de dados. A primeira linha do intervalo contém os nomes dos campos e as linhas subsequentes são registros com valores de campo correspondentes.

   Uma maneira de definir o intervalo de células é inserir a referência de célula para a célula superior esquerda, seguida por dois pontos (:) e, em seguida, a referência de célula inferior direita. Um exemplo pode ser A1:E10.

   O argumento BancoDeDados também pode ser especificado passando o nome de um intervalo nomeado ou intervalo do banco de dados. Usar um nome significativo para definir o intervalo de células pode melhorar a legibilidade da fórmula e a manutenção do documento. Se o nome não corresponder ao nome de um intervalo definido, o Calc reporta um erro #NOME?.

   Outros erros que podem ser relatados como resultado de um argumento BancoDeDados inválido são #VALOR! e Err:504 (erro na lista de parâmetros).

2. Argumento CampoBancoDeDados

   CampoBancoDeDados especifica a coluna que a função usará para seus cálculos depois que os critérios de pesquisa foram aplicados e as linhas de dados foram selecionadas. Não está relacionado aos critérios de pesquisa.

   Especifique o argumento CampoBancoDeDados de uma das seguintes maneiras:

   - Ao Inserir uma referência a uma célula de cabeçalho na área BancoDeDados. Como alternativa, se a célula recebeu um nome significativo como um intervalo nomeado ou intervalo de banco de dados, digite esse nome. Se o nome não corresponder ao nome de um intervalo definido, o Calc reporta um erro #NOME?. Se o nome for válido, mas não corresponder a apenas uma célula, o Calc reporta Err:504 (erro na lista de parâmetros).

   - Ao inserir um número para especificar a coluna na área BancoDeDados , começando com 1. Por exemplo, se um BancoDeDados ocupou o intervalo de células D6: H123, digite 3 para indicar a célula de cabeçalho em F6. O Calc espera um valor inteiro entre 1 e o número de colunas definidas no BancoDeDados e ignora qualquer dígito após um ponto decimal. Se o valor for menor que 1, o Calc reporta Err:504 (erro na lista de parâmetros). Se o valor for maior que o número de colunas no BancoDeDados, o Calc reporta um erro #VALOR!.

   - Ao inserir o nome literal do cabeçalho da coluna da primeira linha do intervalo do BancoDeDados, colocando aspas ao redor do nome do cabeçalho. Por exemplo, “Distância até a escola”. Se a string não corresponder a um dos cabeçalhos de coluna da área BancoDeDados, o Calc reporta Err:504 (erro na lista de parâmetros). Você também pode fornecer uma referência a uma célula arbitrária (fora das áreas BancoDeDados e CritérioDePesquisa) que contém a string necessária.

   O argumento CampoDancoDeDados é opcional para as funções BDCONTAR e BDCONTARA, mas é necessário para as outras dez funções de banco de dados.

3. Argumento CriterioDePesquisa

   CriterioPesquisa especifica o intervalo de células que contém os critérios de pesquisa. Tal como BancoDeDados , sua primeira linha também contém nomes de campo e as linhas subsequentes são condições para campos relacionados. As áreas BancoDeDados e CriterioPesquisa não precisam ser adjacentes, ou mesmo na mesma planilha.

   Uma maneira de definir o intervalo de células é inserir a referência de célula para a célula superior esquerda, seguida por dois pontos (:) e, em seguida, a referência de célula inferior direita. Por exemplo, A13:B14. O intervalo de células também pode ser especificado passando o nome de um intervalo nomeado definido ou intervalo de banco de dados. Se o nome não corresponder ao nome de um intervalo definido, o Calc reporta um erro #NOME?.

   O erro Err:504 (erro na ista de parâmetros) pode ser resultados de um argumento CriterioPesquisa inválido.

   O conteúdo da área CriterioPesquisa é descrito com mais detalhes na próxima seção.

### Definir critérios de pesquisa

O número de colunas ocupadas pela área CriterioPesquisa não precisa ser igual à largura da área BancoDeDados. Todos os cabeçalhos que aparecem na primeira linha do CriterioPesquisa devem ser idênticos aos cabeçalhos da primeira linha do BancoDeDados. No entanto, nem todos os cabeçalhos em BancoDeDados precisam aparecer na primeira linha de CriterioPesquisa, enquanto um cabeçalho em BancoDeDados pode aparecer várias vezes na primeira linha de CriterioPesquisa.

Os critérios de pesquisa são inseridos nas células da segunda linha e nas subsequentes da área CriterioPesquisa, abaixo da linha que contém os cabeçalhos. As células em branco na área CriterioPesquisa são ignoradas.

Crie critérios nas células da área CriterioPesquisa usando os operadores de comparação <, <=, =, <>,> = e>. Assume-se = se uma célula não está vazia, e não começa com um operador de comparação.

Se você escrever vários critérios numa linha, eles serão conectados por E. Se escrever vários critérios em linhas diferentes, eles serão conectados por OU.

Critérios podem ser criados com caracteres curinga, desde que estejam ativados na opção Permitir caracteres curingas em fórmulas na caixa de diálogo LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular. Se a interoperabilidade com o Microsoft Excel for importante esta opção deve ficar ativada.

Critérios ainda mais poderosos podem ser criados com expressões regulares, desde que estejam ativadas na opção Permitir expressões regulares em fórmulas na caixa de diálogo LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular.

Ao usar funções onde um ou mais argumentos são textos de critérios de pesquisa que representam uma expressão regular, a primeira tentativa é de converter o texto do critério em número. Por exemplo, ".0" se converterá em 0.0 e assim por diante. Se tiver sucesso, a verificação não será por expressão regular, mas por conversão numérica. Entretanto, ao mudar de região onde o separador decimal não é mais o ponto, a expressão regular passa a valer. Para forçar a avaliação da expressão regular de uma expressão numérica, utilize uma expressão que não possa ser confundida com um número, como por exemplo, .[0]" ou ".\0" or mesmo "(?i).0".

Outra configuração que afeta a forma como os critérios são tratados é Critérios de pesquisa devem ser = e <> devem ser aplicados ao conteúdo integral das células na caixa de diálogo LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular. Esta opção controla se os critérios de pesquisa definidos para as funções de banco de dados devem corresponder exatamente a toda a célula. Quando a interoperabilidade com o Microsoft Excel é importante para sua planilha, esta opção deve ser habilitada.

### Exemplo de utilização das funções de banco de dados

A tabela a seguir fornece um exemplo de tabela de banco de dados que é utilizado para demonstrar como usar as funções na categoria Banco de dados. O intervalo de células A1: E10 contém informações fictícias sobre os convidados para a festa de aniversário de Joe. As seguintes informações são fornecidas para cada hóspede - nome, série escolar, idade em anos, distância até a escola em metros e peso em quilogramas.

| A | B | C | D | E
1 | Nome | Série | Idade | Distância | Peso
2 | André | 3 | 9 | 150 | 40
3 | Bete | 4 | 10 | 1000 | 42
4 | Carlos | 3 | 10 | 300 | 51
5 | Daniel | 5 | 11 | 1200 | 48
6 | Eva | 2 | 8 | 650 | 33
7 | Francisco | 2 | 7 | 300 | 42
8 | Greta | 1 | 7 | 200 | 36
9 | Henrique | 3 | 9 | 1200 | 44
10 | Irene | 2 | 8 | 1000 | 42
11 |  |  |  |  |

Os seis exemplos a seguir usam a tabela do banco de dados acima, combinada com diferentes áreas de critérios de pesquisa.

#### Exemplo 1

| A | B | C | D | E
12 | Nome | Série | Idade | Distância | Peso
13 |  |  |  | >600 |
14 |  |  |  |  |

Como neste exemplo simples, às vezes é desejável (mas não essencial) colocar a área de critérios de pesquisa diretamente sob a tabela do banco de dados, com as colunas das duas áreas alinhadas verticalmente. As entradas em branco na área de critérios de pesquisa são ignoradas. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula =BDCONTAR(A1:E10;;A12:E14) numa célula vazia em outra parte da planilha para contar como muitos dos convidados de Joe viajam mais de 600 metros para a escola. Retorna o valor 5 (contando Bete, Daniel, Eva, Henrique e Irene).

Observe também que a fórmula =BDCONTAR(A1:E10;; D12:D13) retorna exatamente o mesmo valor, demonstrando que só é necessário que a área de critérios de pesquisa contenha os títulos relevantes das colunas.

#### Exemplo 2

| A | B | C | D | E
12 |  | Idade | Série |  |
13 |  | >7 | 2 |  |
14 |  |  |  |  |

Neste exemplo, a área de critérios de pesquisa contém apenas dois títulos e estes não estão alinhados verticalmente com os títulos correspondentes na tabela de banco de dados de exemplo. Como há duas condições na mesma linha, elas são conectadas por E. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula =BDCONTAR(A1:E10;;B12:C13) numa célula vazia em outra parte da planilha para contar como muitos dos convidados de Joe estão na 2ª série e têm mais de 7 anos de idade. Retorna o valor 2 (contando Eva e Irene).

#### Exemplo 3

| A | B | C | D | E
12 |  | Idade |  |  |
13 |  | 9 |  |  |
14 |  | 10 |  |  |

Neste exemplo, a área de critérios de pesquisa contém apenas um título. Como há duas condições em linhas consecutivas, elas são conectadas por OU. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula =BDCONTAR (A1:E10 ;; B12:B14) numa célula vazia em outra parte da planilha para contar como muitos dos convidados de Joe têm 9 ou 10 anos. Retorna o valor 4 (contando André, Bete, Carlos e Henrique).

#### Exemplo 4

| A | B | C | D | E
12 |  | Idade | Idade |  |
13 |  | >=8 | <=10 |  |
14 |  |  |  |  |

Neste exemplo, a área de critérios de pesquisa contém duas ocorrências do mesmo título. Como há duas condições na mesma linha, elas são conectadas por E. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula =BDCONTAR(A1:E10 ;;B12:C13) numa célula vazia em outra parte da planilha para contar como muitos dos hóspedes de Joe têm entre 8 e 10 anos (inclusive). Retorna o valor 6 (contando André, Bete, Carlos, Eva, Henrique e Irene).

#### Exemplo 5

| A | B | C | D | E
12 | Nome |  |  |  |
13 | F* |  |  |  |
14 |  |  |  |  |

Este exemplo simples mostra o uso de curingas. Para que este exemplo funcione como pretendido, selecione para habilitar curingas em LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula = BDCONTAR(A1:E10 ;;A12:A13) numa célula vazia em outra parte da planilha para contar quantos convidados de Joe têm nomes que começam com a letra “F”. Retorna o valor 1 (contando Frank).

#### Exemplo 6

| A | B | C | D | E
12 | Nome |  |  |  |
13 | [ABC].* |  |  |  |
14 |  |  |  |  |

Este exemplo simples mostra o uso de expressões regulares. Para que este exemplo funcione como pretendido, selecione para ativar as expressões regulares em LibreOffice - PreferênciasFerramentas - Opções - LibreOffice Calc - Calcular. Com a tabela de banco de dados de exemplo acima e esta área de critérios de pesquisa, insira a fórmula =BDCONTAR(A1:E10;;A12:A13) numa célula vazia em outra parte da planilha para contar quantos convidados de Joe têm nomes que começam com as letras “A”, “B” ou “C”. Retorna o valor 3 (contando André, Bete e Carlos).

## BDCONTAR

BDCONTAR conta o número de células (campos) da coluna especificada que contêm valores numéricos, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. No entanto, se nenhuma coluna for especificada, BDCONTAR retorna a contagem de todos os registros que correspondem aos critérios de pesquisa especificados, independentemente de seu conteúdo.

#### Sintaxe

BDCONTAR( BancoDeDados; [ CampoDoBancoDeDados ]; CritérioDePesquisa )

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter "> 600" (este critério de pesquisa irá corresponder aos registros na tabela do banco de dados que têm um valor maior que 600 na coluna Distância).

Insira a fórmula =BDCONTAR(A1:E10 ;; A12:E13) numa célula vazia em outra parte da planilha para calcular quantos convidados da festa de Joe viajam além de 600 metros para a escola. Retorna o valor 5.

O mesmo resultado é obtido se usar a fórmula =BDCONTAR(A1:E10;"Distância";A12:E13), porque todas as entradas na coluna Distância são numéricas. No entanto, se você usar a fórmula =BDCONTAR(A1:E10; "Nome"; A12:E13), retorna o valor 0 porque nenhuma das entradas na coluna Nome é numérica.

## BDCONTARA

BDCONTARA conta o número de células (campos) da coluna especificada que contêm valores não nulos, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. As células em branco da coluna especificada não são contadas. No entanto, se nenhuma coluna for especificada, BDCONTARA retorna a contagem de todos os registros que correspondem aos critérios de pesquisa especificados, independentemente de seu conteúdo.

#### Sintaxe

BDCONTARA(Banco de Dados; [Campo do banco de dados]; Critérios de pesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter "> 600" (este critério de pesquisa irá corresponder aos registros na tabela do banco de dados que têm um valor maior que 600 na coluna Distância).

Insira a fórmula =BDCONTARA(A1:E10 ;; A12:E13) numa célula vazia em outra parte da planilha para calcular quantos convidados da festa de Joe viajam além de 600 metros para a escola. Retorna o valor 5.

O mesmo resultado é obtido se usar a fórmula =BDCONTARA(A1:E10; "Distância"; A12:E13) ou a fórmula =BDCONTARA(A1:E10; "Nome"; A12:E13). O último caso reflete que, em contraste com BDCONTAR, BDCONTARA conta valores numéricos e alfanuméricos na coluna indicada pelo argumento CampoBancoDeDados.

## BDDESVPA

BDDESVPA calcula o desvio padrão da população com base nos valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Valores não numéricos são ignorados.

Retorna um erro #NUM! nenhum registro corresponder aos critérios de pesquisa especificados, ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDDESVPA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:D13 estão em branco, exceto para a célula E13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDDESVPA(A1:E10; "Peso"; A12:E13) numa célula vazia em outra parte da planilha para calcular o desvio padrão da população dos pesos em kg dos convidados da festa de Joe. Retorna o valor 5,18545.

## BDEST

BDEST calcula o desvio padrão de amostras baseado nos valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Valores não numéricos são ignorados.

Retorna um erro #NUM! se somente um registro corresponder aos critérios de pesquisa especificados, ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDEST(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:D13 estão em branco, e a célula E13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDEST(A1:E10; "Peso"; A12:E13) numa célula vazia em outra parte da planilha para calcular o desvio padrão das amostras dos pesos em kg dos convidados da festa de Joe. Retorna o valor 5,5.

## BDEXTRAIR

BDEXTRAIR retorna o conteúdo da célula (campo) da coluna especificada, para a única linha (registro do banco de dados) que corresponde aos critérios de pesquisa especificados.

O Calc reporta Erro:502 (argumento inválido) se várias correspondências forem encontradas, ou um erro #VALOR! (tipo de dados incorreto) se nenhuma correspondência for encontrada. Um erro #VALOR! também é relatado se uma única correspondência for encontrada, mas a célula relevante estiver vazia.

#### Sintaxe

BDEXTRAIR(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula C13 que deve conter "11" (este critério de pesquisa irá corresponder aos registros na tabela do banco de dados que têm um valor de 11 na coluna Idade).

Insira a fórmula =BDEXTRAIR(A1: E10; "Nome"; A12:E13) numa célula vazia em outra parte da planilha para encontrar o nome do convidado da festa de Joe que tem 11 anos de idade. Retorna o nome Daniel.

Ao alterar o valor na célula C13 para “10”, a fórmula =BDEXTRAIR(A1:E10; "Nome"; A12:E13) retorna um erro de argumento inválido (Err: 502). O que reflete que vários registros correspondem ao critério especificado (Bete e Carlos têm 10 anos).

## BDMÁX

BDMÁX calcula o valor máximo nas células (campos) da coluna especificada que contém valores numéricos, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Células ou células em branco contendo caracteres não numéricos não são incluídos.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos diferentes de zero nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDMÁX(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDMÁX(A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para encontrar a distância máxima em metros que qualquer um dos convidados da festa de Joe percorre para a escola. Retorna o valor 1200.

## BDMÉDIA

BDMÉDIA calcula a média dos valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Valores não numéricos em essas células são ignorados.

Retorna um erro #DIV/0! se nenhum registro corresponder aos critérios de pesquisa especificados ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDMÉDIA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDMÉDIA(A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para calcular a distância média em metros percorrida para a escola pelos convidados da festa de Joe. Retorna o valor 666,67.

## BDMÍN

BDMÍN calcula o valor mínimo nas células (campos) da coluna especificada que contém valores numéricos, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Células ou células em branco contendo caracteres não numéricos não são incluídos.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos diferentes de zero nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDMÍN(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDMÍN(A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para encontrar a distância mínima em metros que qualquer um dos convidados da festa de Joe percorre para a escola. Retorna o valor 150.

## BDMULTIPL

BDMULTIPL calcula o produto de todos os valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Célula em branco ou células contendo caracteres não numéricos não são incluídos.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDMULTIPL(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula C13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDMULTIPL(A1:E10; "Idade"; A12:E13) numa célula vazia em outra parte da planilha para calcular o produto das idades em anos dos convidados da festa de Joe. Retorna o valor 279417600.

## BDSOMA

DSUM calcula a soma de todos os valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Células em branco ou células contendo caracteres não numéricos não são incluídos.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDSOMA(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =DSUM (A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para encontrar a distância total em metros que todos os convidados da festa de Joe viajam para a escola. Retorna o valor 6000.

## BDVAREST

BDVAREST calcula a variância da amostra com base nos valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Valores não numéricos são ignorados.

Retorna um erro #NUM! se somente um registro corresponder aos critérios de pesquisa especificados, ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

Retorna 0 se nenhuma correspondência for encontrada ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDVAREST(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDVAREST (A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para encontrar a variância da amostra das distâncias em metros que os convidados da festa de Joe viajam para a escola . Retorna o valor 193125.

## BDVARP

BDVARP calcula a variância da população com base nos valores numéricos nas células (campos) da coluna especificada, para todas as linhas (registros do banco de dados) que correspondem aos critérios de pesquisa especificados. Valores não numéricos são ignorados.

Retorna um erro #NUM! nenhum registro corresponder aos critérios de pesquisa especificados, ou se não houver valores numéricos nas células da coluna especificada para os registros correspondentes.

#### Sintaxe

BDVARP(BancoDeDados; CampoDoBancoDeDados; CritérioDePesquisa)

#### Exemplo

O exemplo de tabela de banco de dados que fornece informações sobre os convidados para a festa de aniversário de Joe (descrito acima) deve ocupar as células A1:E10. O conteúdo das células A12:E12 deve ser idêntico aos rótulos de cabeçalho da tabela do banco de dados nas células A1:E1. Certifique-se de que as células A13:E13 estão em branco, exceto para a célula D13 que deve conter ">0" (este critério de pesquisa pretende corresponder a todos os registros na tabela do banco de dados).

Insira a fórmula =BDVARP(A1:E10; "Distância"; A12:E13) numa célula vazia em outra parte da planilha para encontrar a variância da população das distâncias em metros que os convidados da festa de Joe viajam para a escola . Retorna o valor 171667,67.

Tópicos relacionados

Funções por categoria