سۆزلىشىش رامكا تەھرىرلىگۈچتىكى كونترولنىڭ پروگرامما تۈزۈش مىسالى

Contents
Index 🔎︎

# Programming Examples for Controls in the Dialog Editor

تۆۋەندىكى مىسالدا "Dialog1" ئاتلىق سۆزلىشىش رامكا غا قارىتىلغان. سۆزلىشىش رامكا تەھرىرلىگۈچتىكى قورال ساندۇقى ستونىدىكى قوراللارنى ئىشلىتىپ سۆزلىشىش رامكىسى قۇرۇپ، تۆۋەندىكى كونتروللارنى قوشالايسىز: "CheckBox1" ئاتلىقتاللاش رامكىسى ، "Label1" ئاتلىق بەلگە سۆز بۆلىكى، "CommandButton1" ئاتلىق كۇنۇپكا ۋە "ListBox1" ئاتلىق تىزىملىك رامكىسى.

كونترولنى ئوبيېكت ئۆزگەرگۈچى مىقدارغا قوشقاندا ئىشلەتكەن چوڭ كىچىك ھەرپلەرنىڭ بىردەكلىكىنى ساقلاڭ.

### سۆزلىشىش رامكىسىنىڭ ئومۇمىي فۇنكسىيىسىنى يۈكلەۋاتىدۇ

    Function LoadDialog(Libname as String, DialogName as String, Optional oLibContainer)
    Dim oLib as Object ' com.sun.star.script.XLibraryContainer
    Dim oLibDialog as Object
    Dim oRuntimeDialog as Object
        If IsMissing(oLibContainer) Then
            oLibContainer = DialogLibraries
        End If
        oLibContainer.LoadLibrary(LibName)
        oLib = oLibContainer.GetByName(Libname)
        oLibDialog = oLib.GetByName(DialogName)
        oRuntimeDialog = CreateUnoDialog(oLibDialog)
        LoadDialog() = oRuntimeDialog
    End Function

LoadDialog function is stored in Tools.ModuleControls available from LibreOffice Macros and Dialogs.

### سۆزلىشىش رامكىسى كۆرسىتىۋاتىدۇ

    rem ئومۇمىي ئۆزگەرگۈچى مىقدارنىڭ ئېنىقلىمىسى
    Dim oDialog1 AS Object
    Sub StartDialog1
        With GlobalScope.BasicLibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.ModuleControls.LoadDialog("Standard", "Dialog1")
        oDialog1.Execute()
    End Sub

### پروگراممىدىكى كونترولنىڭ خاسلىقىنى ئوقۇش ياكى تەھرىرلەش

    Sub Sample1
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.LoadDialog("Standard", "Dialog1")
        REM سۆزلىشىش رامكا مودىلىغا ئېرىشىدۇ
        oDialog1Model = oDialog1.Model
        REM  Label1 نىڭ خېتىنى كۆرسىتىدۇ
        oLabel1 = oDialog1.GetControl("Label1")
        MsgBox oLabel1.Text
        REM كونترول Label1 نىڭ يېڭى خېتىنى تەڭشەيدۇ
        oLabel1.Text = "New Files"
        REM كونترول CheckBox1 نىڭ مودىل خاسلىقىنى كۆرسىتىدۇ
        oCheckBox1Model = oDialog1Model.CheckBox1
        MsgBox oCheckBox1Model.Dbg_Properties
        REM  CheckBox1 نىڭ كونترول مودىلىغا يېڭى ھالەت تەڭشەيدۇ
        oCheckBox1Model.State = 1
        REM كونترول CommandButton1 نىڭ مودىلى خاسلىقىنى كۆرسىتىدۇ
        oCMD1Model = oDialog1Model.CommandButton1
        MsgBox oCMD1Model.Dbg_Properties
        REM كونترول CommandButton1 نىڭ خاسلىقىنى كۆرسىتىدۇ
        oCMD1 = oDialog1.GetControl("CommandButton1")
        MsgBox oCMD1.Dbg_Properties
        REM سۆزلىشىش رامكا ئىجرا قىل
        oDialog1.Execute()
    End Sub

### تىزىملىك رامكىسىغا تۈر قوشىدۇ

    Sub AddEntry
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = ModuleControls.LoadDialog("Standard", "Dialog1")
        REM  ListBox قا يېڭى تۈر قوشىدۇ
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        Dim iCount as integer
        iCount = oListbox.ItemCount
        oListbox.additem("New Item" & iCount,0)
    End Sub

### ListBox دىكى تۈرنى چىقىرىۋېتىدۇ

    Sub RemoveEntry
        With GlobalScope.Basiclibraries
           If Not .IsLibraryLoaded("Tools") Then .LoadLibrary("Tools")
        End With
        oDialog1 = Tools.ModuleControls.LoadDialogLoadDialog("Standard", "Dialog1")
        REM  ListBox دىكى بىرىنچى تۈرنى ئۆچۈرىدۇ
        oDialog1Model = oDialog1.Model
        oListBox = oDialog1.GetControl("ListBox1")
        oListbox.removeitems(0,1)
    End Sub

Related Topics

سۆزلىشىش رامكا تەھرىرلىگۈچتىكى كونترولنىڭ خاسلىقىنى ئۆزگەرتىۋاتىدۇ

Basic سۆزلىشىش رامكىسى قۇرۇۋاتىدۇ

سۆزلىشىش رامكا تەھرىرلىگۈچتە كونترول قۇرۇۋاتىدۇ.

Opening a Dialog With Basic