class:: Mix
summary:: Sum an array of channels.
categories::  UGens>Multichannel


Description::

Mix will mix an array of channels down to a single channel or an array
of arrays of channels down to a single array of channels.
More information can be found under link::Guides/Multichannel-Expansion::.


note::

Note that  code::Mix.ar::  and  code::Mix.kr::  in
SC2 are equivalent to  code::Mix.new::  in SC3,
and that  code::Mix.arFill::  and  code::Mix.krFill::  are
equivalent to  code::Mix.fill::.

::

classmethods::

method::new

argument::array
The array of channels or arrays.

method::fill

argument::n
The size of array to create.

argument::function
The array filling function.

returns:: Returns:
A newly created
link::Classes/UGen:: .

Examples::

code::

s.boot;

{ Mix.new([ PinkNoise.ar(0.1), FSinOsc.ar(801, 0.1), LFSaw.ar(40, 0.1)]) }.play

(
play({
	Mix.new( Array.fill(8, { SinOsc.ar(500 + 500.0.rand, 0, 0.05) }) );
}))

(
play({
	Mix.fill(8, { SinOsc.ar(500 + 500.0.rand, 0, 0.05) });
}))

::

